home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / yase.arc / VSCREEN.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-12-13  |  4.4 KB  |  120 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. *****************************************************************
  13. * Virtual Screen - Maintains a virtual interface to a slow 
  14. * CRT output device. Scrolling not supported.
  15.  
  16. lines    equ    24        * lines on actual screen
  17. cols    equ    80        * columns on actual screen
  18.     
  19.     xdef    cls,cursor,putc,sync_curs,v_scrn
  20.     xref    _crt_cls,_crt_put,_crt_cursor    
  21.  
  22. * CLS
  23. * Clears the CRT. No parameters.
  24. *
  25. * CURSOR
  26. * Sets the cursor to an (X,Y) position. Calling sequence: push
  27. * Y, then X. X and Y are binary, zero-based, word length.
  28. * 
  29. * PUTC
  30. * Outputs a character to the display. Calling sequence: push
  31. * the character to be output in the low byte os a word.
  32. *
  33. * SYNC_CURS
  34. * Syncs the actual CRT cursor the the virtual CRT cursor, as it
  35. * usually isn't where it ought to be, especially when doing
  36. * inputs. No parameters.
  37. *****************************************************************
  38. cls:
  39.     movem.l    a0/d0/d1,-(a7)    * save user's registers
  40.     move.w    #(lines*cols),d0  Number of chars to blank
  41.     lsr.w    #1,d0        * Divide by to for word store
  42.     move.w    #'  ',d1    * we'll use register for speed
  43.     move.l    #v_scrn,a0    * our memory copy
  44.     bra    loop_test    * Go do loop test
  45. loop:
  46.     move.w    d1,(a0)+    * store two blanks at a crack
  47. loop_test:
  48.     dbra    d0,loop        * loop thru all memory    
  49.     bsr    _crt_cls    * clear physical screen
  50.     move.w    #1,sync        * set sync flag true
  51.     move.l    #v_scrn,my_curs    * sync my cursor
  52.     clr.l    -(a7)        * put two zero words on stack
  53.     bsr    _crt_cursor    * sync user's cursor
  54.     addq.l    #4,a7        * adjust stack
  55.     clr.w    his_lin        * clear user's line counter
  56.     clr.w    his_col        * clear user's column counter
  57.     movem.l    (a7)+,a0/d0/d1    * restore user's registers
  58.     rts
  59. *****************************************************************
  60. * Sets cursor to arbitrary screen location
  61. cursor:
  62.     clr.w    sync        * set sync flag false    
  63.     move.w    4(a7),his_col    * save crt screen X position
  64.     move.w    6(a7),his_lin    * save crt screen Y position
  65.     move.l    d0,-(a7)    * save D0 across calculation
  66.     clr.l    d0        * start with clean register
  67.     move.w    10(a7),d0    * get new line number
  68.     mulu    #cols,d0    * multiply by cols to get offset
  69.     add.w    8(a7),d0    * add in column offset
  70.     add.l    #v_scrn,d0    * add base to get address
  71.     move.l    d0,my_curs    * now we should be at same spot
  72.     move.l    (a7)+,d0    * restore d0
  73.     rts
  74. *****************************************************************
  75. * Output character to screen if necessary
  76. putc:
  77.     link    a6,#0        * freeze stack frame
  78.     movem.l    d0/a0,-(a7)    * save user's stuff
  79.     move.w    8(a6),d0    * get char to output
  80.     move.l    my_curs,a0    * get my screen address
  81.     cmp.b    (a0),d0        * are they the same?
  82.     beq    no_put        * jump if yes
  83.     move.b    d0,(a0)        * Store char in virtual screen
  84.     tst.w    sync        * are we synced?
  85.     bne    synced        * jumps if synced
  86.     bsr    sync_curs    * sync cursors
  87. synced:
  88.     move.w    8(a6),-(a7)    * push his character
  89.     bsr    _crt_put    * send to crt
  90.     addq.l    #2,a7        * adjust stack
  91.     bra    did_put        * set other vars
  92. no_put:
  93.     clr.w    sync        * show out of sync
  94. did_put:
  95.     addq.l     #1,my_curs    * increment my cursor
  96.     addq.w    #1,his_col    * and his column count
  97.     movem.l    (a7)+,d0/a0    * restore user's stuff
  98.     unlk    a6
  99.     rts
  100. *****************************************************************
  101. * SYNC_CURS - Syncs crt cursor to virtual cursor
  102. sync_curs:
  103.     move.w    d0,-(a7)    * Saving char across put call
  104.     move.w    his_lin,-(a7)    * Push Y address
  105.     move.w    his_col,-(a7)    * Push X address
  106.     bsr    _crt_cursor    * set actual cursor
  107.     addq.l    #4,a7        * adjust stack
  108.     move.w    #1,sync        * show synced
  109.     move.w    (a7)+,d0    * restore character
  110.     rts
  111. *****************************************************************
  112.     bss
  113. sync:    ds.w    1        * actual display synced flag
  114. v_scrn:    ds.b    (lines*cols)    * virtual screen memory
  115. my_curs:ds.l    1        * virtual screen cursor location
  116. his_lin:ds.w    1        * actual screen line number
  117. his_col:ds.w    1        * actual screen column number
  118.  
  119.     end
  120.